mirror of
https://github.com/joaotavora/yasnippet.git
synced 2025-10-13 05:03:04 +00:00
304c01a44a
* yasnippet-debug.el (yas--condition-cache-timestamp): Move it before first use. (yas-debug-live-marker, yas-debug-live-range, yas-debug-snippet-vars) (yas-debug-process-command-line): Remove or mark unused variable/parameters. (yas--letenv): Use `cl-progv'. (yas--mirror-update-display): Remove unused SNIPPET parameter, update caller.
363 lines
16 KiB
EmacsLisp
363 lines
16 KiB
EmacsLisp
;;; yasnippet-debug.el --- debug functions for yasnippet -*- lexical-binding: t -*-
|
||
|
||
;; Copyright (C) 2010, 2013, 2014, 2017 Free Software Foundation, Inc.
|
||
|
||
;; Author: João Távora
|
||
;; Keywords: emulations, convenience
|
||
|
||
;; This program is free software; you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; This program is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;; Some debug functions. When loaded from the command line, provides
|
||
;; quick way to test out snippets in a fresh Emacs instance.
|
||
;;
|
||
;; emacs -Q -l yasnippet-debug [-v[v]]
|
||
;; [-M:<modename>] [-M.<filext>] [-S:[<snippet-file|name>]]
|
||
;; [-- <more-arguments-passed-to-Emacs>...]
|
||
;;
|
||
;; See the source in `yas-debug-process-command-line' for meaning of
|
||
;; args.
|
||
;;
|
||
;;; Code:
|
||
|
||
(defconst yas--loaddir
|
||
(file-name-directory (or load-file-name buffer-file-name))
|
||
"Directory that yasnippet was loaded from.")
|
||
|
||
(require 'yasnippet (expand-file-name "yasnippet" yas--loaddir))
|
||
(require 'cl-lib)
|
||
(eval-when-compile
|
||
(unless (require 'subr-x nil t)
|
||
(defmacro when-let (key-val &rest body)
|
||
(declare (indent 1) (debug ((symbolp form) body)))
|
||
`(let ((,(car key-val) ,(cadr key-val)))
|
||
(when ,(car key-val)
|
||
,@body)))))
|
||
|
||
(defvar yas-debug-live-indicators
|
||
(make-hash-table :test #'eq))
|
||
|
||
(defun yas-debug-live-colors ()
|
||
(let ((colors ()))
|
||
(maphash (lambda (_k v) (push (nth 1 (car v)) colors)) yas-debug-live-indicators)
|
||
colors))
|
||
|
||
(defvar yas-debug-recently-live-indicators)
|
||
|
||
(defun yas-debug-get-live-indicator (location)
|
||
(require 'color)
|
||
(when (boundp 'yas-debug-recently-live-indicators)
|
||
(push location yas-debug-recently-live-indicators))
|
||
(let (beg end)
|
||
(if (markerp location)
|
||
(setq beg (setq end (marker-position location)))
|
||
(setq beg (yas-debug-ov-fom-start location)
|
||
end (yas-debug-ov-fom-end location)))
|
||
(or (when-let (color-ov (gethash location yas-debug-live-indicators))
|
||
(if (and beg end) (move-overlay (cdr color-ov) beg end)
|
||
(delete-overlay (cdr color-ov)))
|
||
color-ov)
|
||
(let* ((live-colors (yas-debug-live-colors))
|
||
(color
|
||
(cl-loop with best-color = nil with max-dist = -1
|
||
for color = (format "#%06X" (random #x1000000))
|
||
for comp = (apply #'color-rgb-to-hex (color-complement color))
|
||
if (< (color-distance color (face-foreground 'default))
|
||
(color-distance comp (face-foreground 'default)))
|
||
do (setq color comp)
|
||
for dist = (cl-loop for c in live-colors
|
||
minimize (color-distance c color))
|
||
if (or (not live-colors) (> dist max-dist))
|
||
do (setq best-color color) (setq max-dist dist)
|
||
repeat (if live-colors 100 1)
|
||
finally return `(:background ,best-color)))
|
||
(ov (make-overlay beg end)))
|
||
(if (markerp location)
|
||
(overlay-put ov 'before-string (propertize "↓" 'face color))
|
||
(overlay-put ov 'before-string (propertize "↘" 'face color))
|
||
(overlay-put ov 'after-string (propertize "↙" 'face color)))
|
||
(puthash location (cons color ov) yas-debug-live-indicators)))))
|
||
|
||
(defun yas-debug-live-marker (marker)
|
||
(let* ((color-ov (yas-debug-get-live-indicator marker))
|
||
(color (car color-ov))
|
||
(ov (cdr color-ov))
|
||
(decorator (overlay-get ov 'before-string))
|
||
(str (format "at %d" (+ marker))))
|
||
(if (markerp marker)
|
||
(propertize str
|
||
'cursor-sensor-functions
|
||
`(,(lambda (_window _oldpos dir)
|
||
(overlay-put
|
||
ov 'before-string
|
||
(propertize decorator
|
||
'face (if (eq dir 'entered)
|
||
'mode-line-highlight color)))))
|
||
'face color)
|
||
str)))
|
||
|
||
(defun yas-debug-ov-fom-start (ovfom)
|
||
(cond ((overlayp ovfom) (overlay-start ovfom))
|
||
((integerp ovfom) ovfom)
|
||
(t (yas--fom-start ovfom))))
|
||
(defun yas-debug-ov-fom-end (ovfom)
|
||
(cond ((overlayp ovfom) (overlay-end ovfom))
|
||
((integerp ovfom) ovfom)
|
||
(t (yas--fom-end ovfom))))
|
||
|
||
(defun yas-debug-live-range (range)
|
||
(let* ((color-ov (yas-debug-get-live-indicator range))
|
||
(color (car color-ov))
|
||
(ov (cdr color-ov))
|
||
(decorator-beg (overlay-get ov 'before-string))
|
||
(decorator-end (overlay-get ov 'after-string))
|
||
(beg (yas-debug-ov-fom-start range))
|
||
(end (yas-debug-ov-fom-end range)))
|
||
(if (and beg end (not (integerp beg)) (not (integerp end)))
|
||
(propertize (format "from %d to %d" (+ beg) (+ end))
|
||
'cursor-sensor-functions
|
||
`(,(lambda (_window _oldpos dir)
|
||
(let ((face (if (eq dir 'entered)
|
||
'mode-line-highlight color)))
|
||
(overlay-put ov 'before-string
|
||
(propertize decorator-beg 'face face))
|
||
(overlay-put ov 'after-string
|
||
(propertize decorator-end 'face face)))))
|
||
'face color)
|
||
"<dead>")))
|
||
|
||
(defmacro yas-debug-with-tracebuf (outbuf &rest body)
|
||
(declare (indent 1))
|
||
(let ((tracebuf-var (make-symbol "tracebuf")))
|
||
`(let ((,tracebuf-var (or ,outbuf (get-buffer-create "*YASnippet trace*"))))
|
||
(unless (eq ,tracebuf-var (current-buffer))
|
||
(cl-flet ((printf (fmt &rest args)
|
||
(with-current-buffer ,tracebuf-var
|
||
(insert (apply #'format fmt args)))))
|
||
(unless ,outbuf
|
||
(with-current-buffer ,tracebuf-var
|
||
(erase-buffer)
|
||
(when (fboundp 'cursor-sensor-mode)
|
||
(cursor-sensor-mode +1))
|
||
(setq truncate-lines t)))
|
||
(setq ,outbuf ,tracebuf-var)
|
||
(save-restriction
|
||
(widen)
|
||
,@body))))))
|
||
|
||
|
||
(defun yas-debug-snippet (snippet &optional outbuf)
|
||
(yas-debug-with-tracebuf outbuf
|
||
(when-let (overlay (yas--snippet-control-overlay snippet))
|
||
(printf "\tsid: %d control overlay %s\n"
|
||
(yas--snippet-id snippet)
|
||
(yas-debug-live-range overlay)))
|
||
(when-let (active-field (yas--snippet-active-field snippet))
|
||
(unless (consp (yas--field-start active-field))
|
||
(printf "\tactive field: #%d %s %s covering \"%s\"\n"
|
||
(yas--field-number active-field)
|
||
(if (yas--field-modified-p active-field) "**" "--")
|
||
(yas-debug-live-range active-field)
|
||
(buffer-substring-no-properties (yas--field-start active-field) (yas--field-end active-field)))))
|
||
(when-let (exit (yas--snippet-exit snippet))
|
||
(printf "\tsnippet-exit: %s next: %s\n"
|
||
(yas-debug-live-marker (yas--exit-marker exit))
|
||
(yas--exit-next exit)))
|
||
(dolist (field (yas--snippet-fields snippet))
|
||
(unless (consp (yas--field-start field))
|
||
(printf "\tfield: %d %s %s covering \"%s\" next: %s%s\n"
|
||
(yas--field-number field)
|
||
(if (yas--field-modified-p field) "**" "--")
|
||
(yas-debug-live-range field)
|
||
(buffer-substring-no-properties (yas--field-start field) (yas--field-end field))
|
||
(yas--debug-format-fom-concise (yas--field-next field))
|
||
(if (yas--field-parent-field field) "(has a parent)" "")))
|
||
(dolist (mirror (yas--field-mirrors field))
|
||
(unless (consp (yas--mirror-start mirror))
|
||
(printf "\t\tmirror: %s covering \"%s\" next: %s\n"
|
||
(yas-debug-live-range mirror)
|
||
(buffer-substring-no-properties (yas--mirror-start mirror) (yas--mirror-end mirror))
|
||
(yas--debug-format-fom-concise (yas--mirror-next mirror))))))))
|
||
|
||
(defvar yas-debug-target-buffer nil)
|
||
(defvar-local yas-debug-target-snippets nil)
|
||
(defvar yas-debug-undo nil)
|
||
|
||
(defun yas-toggle-debug-undo (value)
|
||
(interactive (list (not yas-debug-undo)))
|
||
(setq yas-debug-undo value)
|
||
(yas--message 3 "debug undo %sabled" (if yas-debug-undo "en" "dis")))
|
||
|
||
(defadvice yas--snippet-parse-create (before yas-debug-target-snippet (snippet))
|
||
(add-to-list 'yas-debug-target-snippets snippet))
|
||
|
||
(defadvice yas--commit-snippet (after yas-debug-untarget-snippet (snippet))
|
||
(setq yas-debug-target-snippets
|
||
(remq snippet yas-debug-target-snippets))
|
||
(maphash (lambda (k color-ov)
|
||
(delete-overlay (cdr color-ov)))
|
||
yas-debug-live-indicators)
|
||
(clrhash yas-debug-live-indicators))
|
||
|
||
(defun yas-debug-snippets (&optional outbuf hook)
|
||
(interactive (list nil t))
|
||
(condition-case err
|
||
(yas-debug-with-tracebuf outbuf
|
||
(unless (buffer-live-p yas-debug-target-buffer)
|
||
(setq yas-debug-target-buffer nil))
|
||
(with-current-buffer (or yas-debug-target-buffer (current-buffer))
|
||
(when yas-debug-target-snippets
|
||
(setq yas-debug-target-snippets
|
||
(cl-delete-if-not #'yas--snippet-p yas-debug-target-snippets)))
|
||
(let ((yas-debug-recently-live-indicators nil))
|
||
(dolist (snippet (or yas-debug-target-snippets
|
||
(yas-active-snippets)))
|
||
(printf "snippet %d\n" (yas--snippet-id snippet))
|
||
(yas-debug-snippet snippet outbuf))
|
||
(maphash (lambda (loc color-ov)
|
||
(unless (memq loc yas-debug-recently-live-indicators)
|
||
(delete-overlay (cdr color-ov))
|
||
(remhash loc yas-debug-live-indicators)))
|
||
yas-debug-live-indicators))
|
||
(when (and yas-debug-undo (listp buffer-undo-list))
|
||
(printf "Undo list has %s elements:\n" (length buffer-undo-list))
|
||
(cl-loop for undo-elem in buffer-undo-list
|
||
do (printf "%S\n" undo-elem))))
|
||
(when hook
|
||
(setq yas-debug-target-buffer (current-buffer))
|
||
(ad-enable-advice 'yas--snippet-parse-create 'before 'yas-debug-target-snippet)
|
||
(ad-activate 'yas--snippet-parse-create)
|
||
(ad-enable-advice 'yas--commit-snippet 'after 'yas-debug-untarget-snippet)
|
||
(ad-activate 'yas--commit-snippet)
|
||
(add-hook 'post-command-hook #'yas-debug-snippets)
|
||
;; Window management is slapped together, it does what I
|
||
;; want when the caller has a single window open. Good
|
||
;; enough for now.
|
||
(when (eq hook 'create)
|
||
(require 'edebug)
|
||
(edebug-instrument-function 'yas--snippet-parse-create)
|
||
(let ((buf-point (find-function-noselect 'yas--snippet-parse-create)))
|
||
(with-current-buffer (car buf-point)
|
||
(goto-char (cdr buf-point)))))
|
||
outbuf))
|
||
((debug error) (signal (car err) (cdr err)))))
|
||
|
||
(defun yas-debug-snippet-create ()
|
||
(yas-debug-snippets nil 'create))
|
||
|
||
(defun yas-debug-snippet-vars ()
|
||
"Debug snippets, fields, mirrors and the `buffer-undo-list'."
|
||
(interactive)
|
||
(yas-debug-with-tracebuf ()
|
||
(printf "Interesting YASnippet vars: \n\n")
|
||
|
||
(printf "\nPost command hook: %s\n" post-command-hook)
|
||
(printf "\nPre command hook: %s\n" pre-command-hook)
|
||
|
||
(printf "%s live snippets in total\n" (length (yas-active-snippets 'all-snippets)))
|
||
(printf "%s overlays in buffer:\n\n" (length (overlays-in (point-min) (point-max))))
|
||
(printf "%s live snippets at point:\n\n" (length (yas-active-snippets)))
|
||
|
||
(yas-debug-snippets outbuf) ;;FIXME: reference to free variable ‘outbuf’
|
||
|
||
(printf "\nUndo is %s and point-max is %s.\n"
|
||
(if (eq buffer-undo-list t)
|
||
"DISABLED"
|
||
"ENABLED")
|
||
(point-max))
|
||
(unless (eq buffer-undo-list t)
|
||
(printf "Undpolist has %s elements. First 10 elements follow:\n"
|
||
(length buffer-undo-list))
|
||
(let ((first-ten (cl-subseq buffer-undo-list 0
|
||
(min 19 (length buffer-undo-list)))))
|
||
(dolist (undo-elem first-ten)
|
||
(printf "%2s: %s\n" (cl-position undo-elem first-ten)
|
||
(truncate-string-to-width (format "%s" undo-elem) 70)))))
|
||
(display-buffer tracebuf))) ;;FIXME: reference to free variable ‘tracebuf’
|
||
|
||
(defun yas--debug-format-fom-concise (fom)
|
||
(when fom
|
||
(cond ((yas--field-p fom)
|
||
(format "field %s from %d to %d"
|
||
(yas--field-number fom)
|
||
(+ (yas--field-start fom))
|
||
(+ (yas--field-end fom))))
|
||
((yas--mirror-p fom)
|
||
(format "mirror from %d to %d"
|
||
(+ (yas--mirror-start fom))
|
||
(+ (yas--mirror-end fom))))
|
||
(t
|
||
(format "snippet exit at %d"
|
||
(+ (yas--fom-start fom)))))))
|
||
|
||
(defun yas-debug-process-command-line (&optional options)
|
||
"Implement command line processing."
|
||
(setq yas-verbosity 99)
|
||
(setq yas-triggers-in-field t)
|
||
(setq debug-on-error t)
|
||
(let* ((snippet-mode 'fundamental-mode)
|
||
(snippet-key nil))
|
||
(unless options
|
||
(setq options (cl-loop for opt = (pop command-line-args-left)
|
||
while (and opt (not (equal opt "--"))
|
||
(string-prefix-p "-" opt))
|
||
collect opt)))
|
||
(when-let (mode (cl-member "-M:" options :test #'string-prefix-p))
|
||
(setq snippet-mode (intern (concat (substring (car mode) 3) "-mode"))))
|
||
(when-let (mode (cl-member "-M." options :test #'string-prefix-p))
|
||
(setq snippet-mode
|
||
(cdr (cl-assoc (substring (car mode) 2) auto-mode-alist
|
||
:test (lambda (ext regexp) (string-match-p regexp ext))))))
|
||
(switch-to-buffer (get-buffer-create "*yas test*"))
|
||
(funcall snippet-mode)
|
||
(when-let (snippet-file (cl-member "-S:" options :test #'string-prefix-p))
|
||
(setq snippet-file (substring (car snippet-file) 3))
|
||
(if (file-exists-p snippet-file)
|
||
(with-temp-buffer
|
||
(insert-file-contents snippet-file)
|
||
(let ((snippet-deflist (yas--parse-template snippet-file)))
|
||
(yas-define-snippets snippet-mode (list snippet-deflist))
|
||
(setq snippet-key (car snippet-deflist))))
|
||
(yas-reload-all)
|
||
(let ((template (yas--lookup-snippet-1 snippet-file snippet-mode)))
|
||
(if template
|
||
(setq snippet-key (yas--template-key template))
|
||
(error "No such snippet `%s'" snippet-file)))))
|
||
(display-buffer (find-file-noselect
|
||
(expand-file-name "yasnippet.el" yas--loaddir)))
|
||
(when-let (verbosity (car (or (member "-v" options) (member "-vv" options))))
|
||
(set-window-buffer
|
||
(split-window) (yas-debug-snippets
|
||
nil (if (equal verbosity "-vv") 'create t))))
|
||
(yas-minor-mode +1)
|
||
(when snippet-key (insert snippet-key))))
|
||
|
||
(when command-line-args-left
|
||
(yas-debug-process-command-line))
|
||
|
||
(defun yas-exterminate-package ()
|
||
(interactive)
|
||
(yas-global-mode -1)
|
||
(yas-minor-mode -1)
|
||
(mapatoms #'(lambda (atom)
|
||
(when (string-match "yas[-/]" (symbol-name atom))
|
||
(unintern atom obarray)))))
|
||
|
||
(provide 'yasnippet-debug)
|
||
;; Local Variables:
|
||
;; indent-tabs-mode: nil
|
||
;; End:
|
||
;;; yasnippet-debug.el ends here
|